[BAT] execute Scripts Batch como Administrador (com prompt do UAC GUI)

Finalmente tenho um script em lotes para pedir privilégios de administrador em uma GUI.

Isso vai elevar automaticamente a. CMD ou arquivo batch. BAT usando o prompt do UAC padrão.



Basta colocar isso no topo do seu script em lotes.

BatchGotAdmin International-Fix Code:

Código:


@echo off

:: BatchGotAdmin
:-------------------------------------
REM  --> Check for permissions
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"

REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
    echo Requesting administrative privileges...
    goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"

    "%temp%\getadmin.vbs"
    exit /B

:gotAdmin
    if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
    pushd "%CD%"
    CD /D "%~dp0"
:--------------------------------------

<SEU BATCH SCRIPT AQUI>


Isto segue a idéia original, exceto que ele tenta usar o comando cacls em vez de criar uma pasta no diretório do sistema. Isto é um pouco mais limpa. Também é usado código adequado assim que deve funcionar em versões não em inglês do Windows.

BatchGotAdmin Original Code:

Código:



@echo off

:: Get ADMIN Privs
:-------------------------------------
mkdir "%windir%\BatchGotAdmin"
if '%errorlevel%' == '0' (
  rmdir "%windir%\BatchGotAdmin" & goto gotAdmin
) else ( goto UACPrompt )

:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    echo UAC.ShellExecute %0, "", "", "runas", 1 >> "%temp%\getadmin.vbs"

    "%temp%\getadmin.vbs"
    exit /B

:gotAdmin
    if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
    pushd "%CD%"     
    CD /D "%~dp0"
:-------------------------------------
:: End Get ADMIN Privs

<SEU BATCH SCRIPT AQUI>


Créditos -> Evan Greene e update Aaron Thoma.